标签:trimble2rinex4c bat set %% echo sitename nul doy
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
REM 定义转换程序的安装路径(注意32位/64位系统的路径差别,注意盘符差别,此处已定义C:/D:盘,兼容32位/64位系统)
PATH=C:\Program Files (x86)\Trimble\convertToRINEX;D:\Program Files (x86)\Trimble\convertToRINEX;%PATH%
PATH=C:\Program Files\Trimble\convertToRINEX;D:\Program Files\Trimble\convertToRINEX;%PATH%
PATH=%PATH%;D:\Trimble\convertToRINEX-3.14;D:\bin;D:\bin\unixutils
set RinVer3=3.04
set RinVer2=2.11
set hpath=%CD%
set dfilepath=%CD%\Dfiles
set rin3path=%CD%\Rinex-!RinVer3!
set rin2path=%CD%\Rinex-!RinVer2!
REM 观测员组号,请据实修改。
set group=D101
REM 观测员姓名缩写,请据实修改。
set observer=LZG
REM 程序运行者姓名缩写,一般与观测员相同,请据实修改。
set runby=LZG
for %%f in (*.T02) do (
for /F %%b in ("%%f") do set filename=%%b & set sitename=!filename:~0,4!
for /F %%b in ("%%f") do set filename=%%b & set doy=!filename:~4,3!
move !filename! !sitename!!doy!"0".T02 >nul 2>nul
echo Converting !sitename!!doy!0.T02 into RINEX !RinVer3!.
echo.
convertToRinex !sitename!!doy!0.T02 -v !RinVer3! -c -d -s -r %runby% -o %observer% -ag %group% @ParamFile.ini
for %%o in (!sitename!!doy!0.??o) do (
for /F %%b in ("%%o") do set ofilename=%%b & set yy=!ofilename:~9,2!
set r3dir=%rin3path%\!sitename!\!sitename!R!yy!.!doy!
mkdir !r3dir! >nul 2>nul
echo.
echo MOVE !sitename! !doy! !yy! RINEX !RinVer3! files to !r3dir!.
echo.
move !sitename!!doy!0.!yy!? !r3dir! >nul 2>nul
copy ParamFile.ini !r3dir! >nul 2>nul
)
echo Converting !sitename!!doy!0.T02 into RINEX !RinVer2!.
echo.
convertToRinex !sitename!!doy!0.T02 -v !RinVer2! -c -d -s -r %runby% -o %observer% -ag %group% @ParamFile.ini
for %%o in (!sitename!!doy!0.??o) do (
echo.
echo DO TEQC checking for %%o.
echo.
teqc +qc -plot -R -C %%o 1>%%o.TEQC.log 2>%%o.TEQC.ERROR.log
for /F %%b in ("%%o") do set ofilename=%%b & set yy=!ofilename:~9,2!
set ddir=%dfilepath%\!sitename!\!sitename!D!yy!.!doy!
mkdir !ddir! >nul 2>nul
set r2dir=%rin2path%\!sitename!\!sitename!R!yy!.!doy!
mkdir !r2dir! >nul 2>nul
echo MOVE !sitename!!doy!0.T02 to !ddir!.
echo.
move !sitename!!doy!0.T02 !ddir! >nul 2>nul
echo MOVE !sitename! !doy! !yy! RINEX !RinVer2! files to !r2dir!.
echo.
move !sitename!!doy!0.!yy!? !r2dir! >nul 2>nul
copy %%o.TEQC.log !r2dir! >nul 2>nul
copy %%o.TEQC.ERROR.log !r2dir! >nul 2>nul
copy ParamFile.ini !r2dir! >nul 2>nul
)
)
PAUSE
标签:trimble2rinex4c,bat,set,%%,echo,sitename,nul,doy 来源: https://www.cnblogs.com/iliuzhiguang/p/14412016.html
本站声明: 1. iCode9 技术分享网(下文简称本站)提供的所有内容,仅供技术学习、探讨和分享; 2. 关于本站的所有留言、评论、转载及引用,纯属内容发起人的个人观点,与本站观点和立场无关; 3. 关于本站的所有言论和文字,纯属内容发起人的个人观点,与本站观点和立场无关; 4. 本站文章均是网友提供,不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属;如您发现该文章侵犯了您的权益,可联系我们第一时间进行删除; 5. 本站为非盈利性的个人网站,所有内容不会用来进行牟利,也不会利用任何形式的广告来间接获益,纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。