标签：Function Dim VB rs 对象 Byt KeyName ADODB 序列化

'序列化类对象为二进制流
Public Function ObjectToBinary(ByVal KeyName As String, Obj As Object) As Byte()
    Dim Byt() As Byte
    Dim objBag As New PropertyBag
    If Obj Is Nothing Or Len(KeyName) = 0 Then Exit Function
    objBag.WriteProperty KeyName, Obj
    Byt = objBag.Contents
    ObjectToBinary = Byt
End Function

'从二进制流加载对象
Public Function BinaryToObject(ByVal KeyName As String, Byt() As Byte) As Object
    Dim oP As New PropertyBag
    If Len(KeyName) = 0 Then Exit Function
    oP.Contents = Byt
    Set BinaryToObject = oP.ReadProperty(KeyName)
End Function

'记录集对象序列化为二进制流
'传入的记录集游标需要为 CursorLocation = adUseClient 否则 rs.Save s, adPersistADTG 会报错
Public Function RecordsetToBinary(rs As ADODB.Recordset) As Byte()
    Dim s As New ADODB.Stream
    s.Open
    s.Type = adTypeBinary
    rs.Save s, adPersistADTG
    RecordsetToBinary = s.Read()
    Set s = Nothing
End Function

'二进制流转换为记录集
Public Function BinaryToRecordset(Byt() As Byte) As ADODB.Recordset
    Dim s As New ADODB.Stream
    Dim rs As New ADODB.Recordset
    s.Open
    s.Type = adTypeBinary
    s.Write Byt
    s.Position = 0
    rs.Open s
    Set BinaryToRecordset = rs
End Function

标签：Function,Dim,VB,rs,对象,Byt,KeyName,ADODB,序列化
来源： https://blog.csdn.net/KingZhang2000/article/details/88614880

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。