标签：sStr Delphi SysUtils StringReplace Hi 字符串 OldPattern 替换

Delphi 字符串替换 SysUtils.StringReplace

StringReplace  返回一个字符串，其中一个子字符串替换为另一个子字符串。

原型：

function StringReplace(const S, OldPattern, NewPattern: string;
  Flags: TReplaceFlags): string;
var
  SearchStr, Patt, NewStr: string;
  Offset: Integer;
begin
  if rfIgnoreCase in Flags then
  begin
    SearchStr := AnsiUpperCase(S);
    Patt := AnsiUpperCase(OldPattern);
  end else
  begin
    SearchStr := S;
    Patt := OldPattern;
  end;
  NewStr := S;
  Result := '';
  while SearchStr <> '' do
  begin
    Offset := AnsiPos(Patt, SearchStr);
    if Offset = 0 then
    begin
      Result := Result + NewStr;
      Break;
    end;
    Result := Result + Copy(NewStr, 1, Offset - 1) + NewPattern;
    NewStr := Copy(NewStr, Offset + Length(OldPattern), MaxInt);
    if not (rfReplaceAll in Flags) then
    begin
      Result := Result + NewStr;
      Break;
    end;
    SearchStr := Copy(SearchStr, Offset + Length(Patt), MaxInt);
  end;
end;

描述：

• StringReplace将OldPattern指定的子字符串替换为NewPattern指定的子字符串。StringReplace假定源字符串可能包含多字节字符。
• S是源字符串，其子字符串已更改。
• OldPattern是用来定位并替换为NewPattern的子字符串。
• NewPattern是替换OldPattern的子字符串。
• Flags是一组标志，用于控制StringReplace如何定位和替换OldPattern的引用。如果标志不包括rfReplaceAll，StringReplace只替换S中第一次出现的OldPattern。否则，StringReplace将用NewPattern替换OldPattern的所有实例。如果Flags参数包括rfIgnoreCase，则比较操作不区分大小写。

附.TReplaceFlags 类型（TReplaceFlags指示如何执行搜索和替换操作）

type TReplaceFlags = set of (rfReplaceAll, rfIgnoreCase);

参数：

• rfReplaceAll  //替换所有事件。如果不存在此标志，则只替换第一个出现的目标子字符串。
• rfIgnoreCase  //不敏感地匹配子字符串大小写的出现。如果不存在此标志，则只考虑区分大小写的匹配。

示例：

var
    sStr: String;
begin
    sStr:= 'Hi TaoRoy 2022 ';
    ShowMessage(StringReplace (sStr, 'o', 'i', []));//Hi TaiRoy 2022  替换第一个

    sStr:= 'Hi TaoRoy 2022 ';
    ShowMessage(StringReplace (sStr, 'o', 'i', [rfReplaceAll]));  //Hi TaiRiy 2022  替换所有
    
    sStr:= 'Hi TaoRoy 2022 Open the world ';
    ShowMessage(StringReplace (sStr, 'o', 'i', [rfReplaceAll])); //Hi TaiRiy 2022 Open the wirld  //替换所有，区分大小写
    
    sStr:= 'Hi TaoRoy 2022 Open the world ';
    ShowMessage(StringReplace (sStr, 'o', 'i', [rfReplaceAll, rfIgnoreCase]));//Hi TaiRiy 2022 ipen the wirld  //替换所有，不区分大小写

创建时间：2022.02.17　　更新时间：

标签：sStr,Delphi,SysUtils,StringReplace,Hi,字符串,OldPattern,替换
来源： https://www.cnblogs.com/guorongtao/p/15904496.html

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。