标签：bat set 批量 %% 备份 echo nul adb REM

@echo off
REM adb工具包文件夹
set "adbPath=G:\Phone\tool"
REM 照片保存文件夹
set "imgPath=G:\DCIM"
REM 视频保存文件夹
set "mp4Path=G:\video"
set "path=%path%;%adbPath%"
REM 检测设备
adb devices | findstr /e /i "device" >nul 2>nul || ( adb devices & echo No Devices! & pause&exit )
mkdir "%imgPath%" "%mp4Path%" >nul 2>nul
REM 备份照片
for /f "delims=" %%i in ('adb shell find /sdcard/dcim -name "*.jpg"') do (
    set /p "=pull %%i  "<nul
    if not exist "%imgPath%\%%~nxi" (
        adb pull "%%i" "%imgPath%\%%~nxi" >nul 2>nul
        echo done!
    ) else echo skip 
)
REM 备份视频
for /f "delims=" %%i in ('adb shell find /sdcard/dcim -name "*.mp4"') do (
    set /p "=pull %%i  "<nul
    if not exist "%mp4Path%\%%~nxi" (
        adb pull "%%i" "%mp4Path%\%%~nxi" >nul 2>nul
        echo done!
    ) else echo skip 
)
pause&exit

标签：bat,set,批量,%%,备份,echo,nul,adb,REM
来源： https://www.cnblogs.com/ai594ai/p/15019953.html

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。