给 "水桶" 同学解释一下 "流" 类中的 Seek() 方法

2021-06-06 22:06:05 阅读：246 来源： 互联网

标签：stream Read IntToStr 解释一下 Position ShowMessage Seek 类中

给 "水桶" 同学解释一下 "流" 类中的 Seek() 方法
问题来源: http://www.cnblogs.com/del/archive/2008/01/01/1022130.html#2103357

TStream 有 Seek() 方法, 它的子类们(TFileStream、TMemoryStream、TBytesStream、TStringStream、TResourceStream、TStreamAdapter、THandleStream...)也都有 Seek() 方法, 且用法一样.

另外它们也都有 Position 属性, 使用 Position 属性完全可以代替 Seek() 方法, 通过 Position 还可以方便地 "读取" 当前位置;
但如果只是移动位置, 使用 Seek() 方法更方便.

方法的参数: Seek(偏移量, 偏移的起始点), 返回值是偏移后的当前位置.
偏移量: 以字节为单位, 负值表示向前偏移;
起始点: 0 表示从头算起、1 表示从当前位置算起、2 表示从尾部算起; 从尾部算起时, 偏移量应该是个负值.

指示起始点时, 可以使用 soFromBeginning、soFromCurrent、soFromEnd 三个常数, 但最好使用枚举 TSeekOrigin = (soBeginning, soCurrent, soEnd);
Seek() 方法有两个重载, 就是可以使用常数、也可以使用枚举来标识偏移的起始点.

例子:

procedure TForm1.FormCreate(Sender: TObject);
var
  stream: TBytesStream; //以字节流举例
  C: Char; //用于读取字符的变量
begin
  {建立并初始化化流}
  stream := TBytesStream.Create(BytesOf('ABCDEFGHIJKLMNOPQRSTUVWXYZ'));
  ShowMessage(StringOf(stream.Bytes)); //测试赋值结果: ABCDEFGHIJKLMNOPQRSTUVWXYZ

  {从起始点读取一个字符}
  stream.Position := 0;
  stream.Read(C, 1);
  ShowMessage(C); //A

  {Read() 和 Write() 方法都会更新当前位置, 继续读取:}
  stream.Read(C, 1);
  ShowMessage(C); //B

  {...}
  stream.Seek(3, soBeginning);
  ShowMessage(IntToStr(stream.Position)); //3

  stream.Seek(2, soCurrent);
  ShowMessage(IntToStr(stream.Position)); //5

  stream.Seek(-2, soCurrent);
  ShowMessage(IntToStr(stream.Position)); //3

  stream.Seek(-1, soEnd);
  ShowMessage(IntToStr(stream.Position)); //25
  stream.Read(C, 1);
  ShowMessage(C);                         //Z

  stream.Seek(-stream.Size, soEnd);
  ShowMessage(IntToStr(stream.Position)); //0
  stream.Read(C, 1);
  ShowMessage(C);                         //A

  stream.Position := 4;
  ShowMessage(IntToStr(stream.Position)); //4
  stream.Read(C, 1);
  ShowMessage(C);                         //E

  stream.Free;
end;

posted on 2011-05-22 21:54 万一阅读(5981) 评论(7) 编辑收藏

标签：stream,Read,IntToStr,解释一下,Position,ShowMessage,Seek,类中
来源： https://blog.51cto.com/u_14617575/2873187

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。

ICode9

给 "水桶" 同学解释一下 "流" 类中的 Seek() 方法