标签：set 封装 goto listenport windows 端口 listenaddress echo netsh

@echo off
setlocal enabledelayedexpansion
::判断是否为管理员打开
net.exe session 1>NUL 2>NUL && (
    goto start
) || (
    goto UACPrompt
)
   
:UACPrompt  
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs" 
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs" 
    "%temp%\getadmin.vbs" 
    exit /B  


:start
choice /C 1234 /T 15 /D 3 /M "1.查看所有转发列表,2.映射端口,3.删除映射,4.退出"

if errorlevel 4 goto ext
if errorlevel 3 goto del
if errorlevel 2 goto add
if errorlevel 1 goto list

:list
echo ===============================list===============================
netsh interface portproxy show all 
echo ==================================================================
pause
goto start
 
:add
set /p listenaddress=请输入监听的ip地址: 
set /p listenport=请输入监听的端口: 
set /p connectaddress=请输入转发目标的ip地址: 
set /p connectport=请输入转发目标的端口:

echo use "netsh interface portproxy add v4tov4 listenaddress=!listenaddress! listenport=!listenport! connectaddress=!connectaddress! connectport=!connectport!"
netsh interface portproxy add v4tov4 listenaddress=!listenaddress! listenport=!listenport! connectaddress=!connectaddress! connectport=!connectport!
goto list

:del
set /p listenaddress=请输入监听的ip地址: 
set /p listenport=请输入监听的端口: 

echo use "netsh interface portproxy del v4tov4 listenport=!listenport! listenaddress=!listenaddress!"
netsh interface portproxy del v4tov4 listenport=!listenport! listenaddress=!listenaddress!
goto list


:ext
exit 

使用方法：

1.新建空文本文件，将文件名改为：transmit.bat

2.打开文件，将上述代码 复制如文件即可。 注意需要修改一下文本的编码格式为：gb2312

标签：set,封装,goto,listenport,windows,端口,listenaddress,echo,netsh
来源： https://www.cnblogs.com/zjhblogs/p/12049124.html

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。