标签：bat set goto temp% 本地连接 echo DNS 以太网 netsh

有些场景需要测试网络通不通等，每次打开网络和共享中心真烦，win10右下角还进不去了，shit!

运行ncpa.cpl也打开那个界面也是费劲吧啦，索性写个bat吧！为啥要写？还不是因为懒！可以把脚本复制到带有环境变量的目录里，以后直接Win+R就行了。

功能：设置动态/静态IP、掩码、网关、及DNS

效果如下图：

脚本中添加了管理员权限请求，不然权限不足。

我是Win10系统，win7系统命令不大一样，请把38行那ipv4改成ip。注意！还有接口名称，bat中写的是我的有线网卡“以太网”。

@echo off

::请求管理员权限区块开始
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
::请求管理员权限区块结束

:start
set /p oh=静态还是DHCP?(s/d):
if %oh%==s (
goto :static
) else if %oh%==d (
goto :dhcp
) else (
echo 请输入s/d!
echo.
goto :start
)

:static
set /p ip=input ip:
set /p c=255.255.255.0请回车，输入任意键改为其他掩码:
set mask=255.255.255.0
if not "%c%"=="" (
set /p mask=输入掩码(x.x.x.x^)^:
)
set /p gw=input gw(可不填):
set /p dns=input dns(可不填):
netsh interface ipv4 set address "以太网" static %ip% %mask% %gw%
:: Win7系统请改为下面命令↓
:: netsh interface ip set address "以太网" static %ip% %mask% %gw%
if not "%dns%"=="" (
netsh interface ipv4 set dnsservers "以太网" static %dns% validate=no
)
goto :end

:dhcp
netsh interface ipv4 set address "以太网" source=dhcp
netsh interface ipv4 set dnsservers "以太网" source=dhcp

:end
echo.
echo OK!

pause

标签：bat,set,goto,temp%,本地连接,echo,DNS,以太网,netsh
来源： https://www.cnblogs.com/zilong666/p/11032612.html

本站声明： 1. iCode9 技术分享网（下文简称本站）提供的所有内容，仅供技术学习、探讨和分享；
2. 关于本站的所有留言、评论、转载及引用，纯属内容发起人的个人观点，与本站观点和立场无关；
3. 关于本站的所有言论和文字，纯属内容发起人的个人观点，与本站观点和立场无关；
4. 本站文章均是网友提供，不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属；如您发现该文章侵犯了您的权益，可联系我们第一时间进行删除；
5. 本站为非盈利性的个人网站，所有内容不会用来进行牟利，也不会利用任何形式的广告来间接获益，纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。