ICode9

精准搜索请尝试: 精确搜索
首页 > 系统相关> 文章详细

windows 配置nginx环境变量

2022-02-28 22:04:18  阅读:218  来源: 互联网

标签:goto start windows echo nginx exit 环境变量 NGINX


1.情景展示

在开发过程中,当我们将nginx放置到windows操作系统下时,如何在黑窗口下使用命令,对nginx服务器进行操作?

2.具体分析

说明:如果你不想看推导过程,可以直接看解决方案,我推出的解决方案是全网独有的,所以说,不看推导过程,这对于个人能力的提升而言没有任何帮助。

当我们从nginx官网上下载下来windows版本,解压后,如何通过命令启动nginx服务器?

打开命令窗口;

输入:nginx,回车执行;

没有nginx这个命令?这才是正常的现象。

我们现在来回想一下:java是如何配置环境变量的?nginx是不是也可以像java那样配置好环境变量直接使用?

说干就干,一起来试一下:

win+r--》输入:sysdm.cpl

高级--》环境变量;

新建--》变量名可设置为:NGINX_HOME(名称随意,但最好遵循见名知意的原则);

变量值设置为:nginx的根目录。

然后,将其引入到系统变量Path当中。

格式:%变量名%

确定;

重新打开黑窗口,运行nginx命令;

我们可以看到:

第一,nginx命令现在可以使用了,但是启动失败;

第二,报错信息是:在C:\Users\Marydon目录下,找不到conf/nginx.conf文件。

这是怎么回事?我们明明将nginx的根目录已经配好了,为啥nginx要去C:\Users\Marydon目录下找nginx的配置文件?不应该是去nginx的根目录下找吗?

原来,Nginx 在启动时需要找到nginx.conf配置文件, conf-path 是根据相对路径来找的,什么意思?

意思就是:在哪个目录下运行nginx命令,nginx就去该目录下找对应的配置文件,这能找到?能找到就见鬼了!

这些基础命令,是可以正常使用的;

但是,需要用到配置文件的start、stop、reload、reopen等控制命令无法使用,如何解决?

3.解决方案

方案一:在nginx的根目录下运行

我们来到nginx的安装目录,在路径栏输入:cmd,并按回车键;

将会在此目录下运行cmd并打开命令窗口;

输入nginx,并按回车键;

或者,输入:start nginx,并按回车键。

没有报错信息,说明使用nginx服务器启动成功。

以上两种启动方式,打开的都是nginx.exe

相当于:我们双击运行nginx.exe。

当然,这种方式,适合偶尔使用的情况。

另一种方式,就是:创建nginx.exe的桌面快捷方式,什么时候需要用了,什么时候打开,当然,这种方式只能用于启动nginx服务器。

方案二:配置环境变量和创建bat命令

接着第二步分析继续进行,此时环境变量已经配好。

第一,nginx支持在启动时指定 conf-path 的绝对路径,亦或是重新编译 Nginx 来指定 conf-path。

所以,我们在启动nginx时,可以通过 -p 命令来指定nginx所在的绝对路径。

第二,创建bat命令。

使用 bat 来运行 nginx 命令。

新建一个文本文件,将以下代码粘贴进去:

查看代码
@echo off
if "%1"=="help" (goto help) else (if "%1"=="-h" goto help)
if "%1"=="version" (goto version) else (if "%1"=="-v" goto version)
if "%1"=="start" goto start
if "%1"=="stop" goto stop
if "%1"=="reload" goto reload
if "%1"=="reopen" goto reopen
if "%1"=="find" goto find
goto error

:help
nginx -v
echo Usage: nginx2 [-h,help] [-v,version] [start] [stop] [stop -a] [reload] [reopen] [find]
echo=
echo Options:
echo   help,-h         : this help
echo   version,-v      : show current nginx version
echo   start           : start nginx master process
echo   stop            : stop the newest nginx master process
echo   stop -a         : stop all nginx master processes
echo   reload          : reload configuration
echo   reopen          : reopen nginx
echo   find            : show the nginx master process list
echo=
exit /B

:version
nginx -v
exit /B

:start
start nginx -p %NGINX_HOME%
exit /B

:stop
if "%2"=="-a" (taskkill /F /IM nginx.exe) else (if "%2"=="" (nginx -s stop -p %NGINX_HOME%) else goto error)
exit /B

:reload
nginx -s reload -p %NGINX_HOME%
exit /B

:reopen
nginx -s reopen -p %NGINX_HOME%
exit /B

:find
tasklist /fi "imagename eq nginx.exe"
exit /B

:error
echo nginx2: invalid option: "%1 %2"
echo=   
exit /B

保存,将文件重命名为:nginx2.bat;

将其拷贝到nginx根目录下;

 

重新打开cmd命令,启动nginx服务器。

在浏览器输入:localhost进行访问,进入nginx欢迎页。

我们可以使用的命令有:

优点:解决了nginx服务器通过相对路径访问配置文件的问题。

缺点:但是这样虽然可操作nginx服务器,但是,不需要配置文件的常用命令,还需要我们使用nginx的命令来操作;

另外,由于启动、关闭、重启服务器和重新加载配置文件,是我们自定义的命令,一旦我们换台机器,咱们还需要记住原来的操作命令,相当于需要记忆两套命令;

这样一来,其实,与我们的原来目的背道而驰,因为虽然间接实现了,但我们是以丧失原nginx命令为前提的,也就是所谓的:顾此失彼。

虽然,这种方式比较鸡肋,但对于window批处理文件的命令还是值得学习的。

bat命令说明:

第一,@echo off 此命令需要将 @ 和 echo off 分开说明:

@让跟在其后面的命令的执行过程不打印出来;echo off 则让所有命令的执行过程不打印出来。

第二,goto 与 :  这两个命令需要配套使用,: 相当于标签(标签名称不区分大小写),goto 指定跳到那个标签后面执行它下面的内容;

第三,echo 向命令窗口打印一行指定的字符串,举例:echo= 打印空的字符串,结果相当于换行。

第四,exit 该命令是退出程序,并且会关闭命令窗口;

exit /B 表示退出程序后不会关闭命令窗口(退回前一个命令所在窗口)。

第五:在bat文件中可以用百分号来引用环境变量,即:%环境变量%;

第六:获取用户输入的数据,用%数字接收,多个参数中间用空格加以区分。

第六:bat文件名称是什么,你调用指令的名称就是什么。

4.再次封装

其实,只要,我们学习一下bat命令,那自定义封装实现起来将会得心应手。

基于上面原作者的基础上进行二次封装

查看代码
@echo off
if "%1"=="-?" (goto help) else (if "%1"=="-h" goto help)
if "%1"=="-v" (goto version)
if "%1"=="-V" (goto version2)
if "%1"=="-t" (goto test)
if "%1"=="-T" (goto test2)
if "%1"=="-q" (goto suppress)
if "%1"=="start" goto start
if "%1"=="-s" goto signal
if "%1"=="-p" goto prefix
if "%1"=="-e" goto error
if "%1"=="-c" goto configuration
if "%1"=="-g" goto global
if "%1"=="search" goto search
if "%1"=="kill" goto kill
goto errors

:help
nginx -v
echo Usage: nginx2 [-?,-h] [-v] [-V] [-t] [-T] [-q] [start] [-s signal] [-p prefix] [-e filename] [-c filename] [-g directives] [search] [kill]
echo=
echo Options:
echo   -?,-h           : this help
echo   -v              : show version and exit
echo   -V              : show version and configure options then exit
echo   -t              : test configuration and exit
echo   -T              : test configuration, dump it and exit
echo   -q              : suppress non-error messages during configuration testing
echo   start           : start nginx master process
echo   -s signal       : send signal to a master process: stop, quit, reopen, reload
echo   -p prefix       : set prefix path (default: NONE)
echo   -e filename     : set error log file (default: logs/error.log)
echo   -c filename     : set configuration file (default: conf/nginx.conf)
echo   -g directives   : set global directives out of configuration file
echo   search            : show the nginx master process list(customize include)
echo   kill            : kill all nginx master processes(customize include)
echo=
exit /B

:version
nginx -v
exit /B

:version2
nginx -V
exit /B

:test
nginx -t -p %NGINX_HOME%
exit /B

:test2
nginx -T -p %NGINX_HOME%
exit /B

:suppress
nginx -q -p %NGINX_HOME%
exit /B

:start
start nginx -p %NGINX_HOME%
exit /B

:signal
nginx -s %2 -p %NGINX_HOME%
exit /B

:prefix
nginx -p %2 -p %NGINX_HOME%
exit /B

:error
nginx -e %2 -p %NGINX_HOME%
exit /B

:configuration
nginx -c %2 -p %NGINX_HOME%
exit /B

:global
nginx -g %2 -p %NGINX_HOME%
exit /B

:search
tasklist /fi "imagename eq nginx.exe"
exit /B

:kill
taskkill /F /IM nginx.exe
exit /B

:errors
echo nginx2: invalid option: "%1 %2"
echo=   
exit /B

原生的nginx命令 

 

这样一来,在nginx可以用的原生指令,我们通过封装,也能保证封装后的指令和它基本上完全一致。

与nginx原生指令的区别,在于:

第一,启动服务器;

原生:start nginx。

派生:nginx2 start。

第二,新增自定义指令;

ngnix2 search:查询nginx服务进程;

ngnix2 kill:杀死所有nginx服务进程。

第三,指令名称不同。 

原生:使用nginx+指令;

派生:使用nginx2+指令。

再次简化

@echo off
if "%1"=="-?" (goto help) else (if "%1"=="-h" goto help)
if "%1"=="-v" (goto vVtTq)
if "%1"=="-V" goto vVtTq
if "%1"=="-t" goto vVtTq
if "%1"=="-T" goto vVtTq
if "%1"=="-q" goto vVtTq
if "%1"=="start" goto start
if "%1"=="-s" goto specg
if "%1"=="-p" goto specg
if "%1"=="-e" goto specg
if "%1"=="-c" goto specg
if "%1"=="-g" goto specg
if "%1"=="search" goto search
if "%1"=="kill" goto kill
goto errors

:help
nginx -v
echo Usage: nginx2 [-?,-h] [-v] [-V] [-t] [-T] [-q] [start] [-s signal] [-p prefix] [-e filename] [-c filename] [-g directives] [search] [kill]
echo=
echo Options:
echo   -?,-h           : this help
echo   -v              : show version and exit
echo   -V              : show version and configure options then exit
echo   -t              : test configuration and exit
echo   -T              : test configuration, dump it and exit
echo   -q              : suppress non-error messages during configuration testing
echo   start           : start nginx master process
echo   -s signal       : send signal to a master process: stop, quit, reopen, reload
echo   -p prefix       : set prefix path (default: NONE)
echo   -e filename     : set error log file (default: logs/error.log)
echo   -c filename     : set configuration file (default: conf/nginx.conf)
echo   -g directives   : set global directives out of configuration file
echo   search            : show the nginx master process list(customize include)
echo   kill            : kill all nginx master processes(customize include)
echo=
exit /B

:vVtTq
nginx %1 -p %NGINX_HOME%
exit /B

:start
start nginx -p %NGINX_HOME%
exit /B

:specg
nginx %1 %2 -p %NGINX_HOME%
exit /B

:search
tasklist /fi "imagename eq nginx.exe"
exit /B

:kill
taskkill /F /IM nginx.exe
exit /B

:errors
echo nginx2: invalid option: "%1 %2"
echo=   
exit /B

 

写在最后

  哪位大佬如若发现文章存在纰漏之处或需要补充更多内容,欢迎留言!!!

 相关推荐:

标签:goto,start,windows,echo,nginx,exit,环境变量,NGINX
来源: https://www.cnblogs.com/Marydon20170307/p/15944960.html

本站声明: 1. iCode9 技术分享网(下文简称本站)提供的所有内容,仅供技术学习、探讨和分享;
2. 关于本站的所有留言、评论、转载及引用,纯属内容发起人的个人观点,与本站观点和立场无关;
3. 关于本站的所有言论和文字,纯属内容发起人的个人观点,与本站观点和立场无关;
4. 本站文章均是网友提供,不完全保证技术分享内容的完整性、准确性、时效性、风险性和版权归属;如您发现该文章侵犯了您的权益,可联系我们第一时间进行删除;
5. 本站为非盈利性的个人网站,所有内容不会用来进行牟利,也不会利用任何形式的广告来间接获益,纯粹是为了广大技术爱好者提供技术内容和技术思想的分享性交流网站。

专注分享技术,共同学习,共同进步。侵权联系[81616952@qq.com]

Copyright (C)ICode9.com, All Rights Reserved.

ICode9版权所有